@echo off
rem GATEUNST.BAT

rem  Test for presence of winbootdir variable to see if Windows '95 is running
rem    or Windows 3.1x.
Set WINTEST=%winbootdir%
if %WINTEST%NO95==NO95 goto :Win31x


rem             Windows' 95 Section
cls
echo.
echo            LANtastic Winsock Gateway Removal Program for Windows '95/98

echo.
echo   This screen should only appear in a Windows '95/98 environment.  If you
echo   see this message on a DOS/Windows 3.1x computer please abort this program,
echo   issue the DOS command SET WINBOOTDIR= and press [Enter.]
echo.
echo   This program may then be relaunched and the Windows 3.1x initialization
echo   screen should appear.  
echo.
echo.
echo   This program permanently removes the LANtastic Winsock Gateway feature of
echo   LANtastic 7.0.  Should you later wish to reenable this feature it will be 
echo   necessary to reinstall LANtastic 7.0 either from CD or from an Install 
echo   resource once this program has completed.
echo.
echo            Press Ctrl-C to abort or
echo.
pause

cls
echo.
echo   Now removing LANtastic Internet Gateway files. . .
c:
cd %winbootdir%
rem                     Creating GateUnst.ini file
echo [HKLM_KEYS] > gateunst.ini
echo KEY1=SOFTWARE\ARTISOFT\WSGateway >> gateunst.ini
echo. >> gateunst.ini
echo [CLASSREMOVE] >> gateunst.ini
echo MODULE1=WSSERVER,NetService >> gateunst.ini

rem                     Append to previous wininit.ini
rem                      otherwise create new one
if exist %winbootdir%\wininit.ini goto :BuildFileList
echo [rename] > wininit.ini

:BuildFileList
echo NUL=%winbootdir%\AIXTHNK.DLL >> wininit.ini
echo NUL=%winbootdir%\AWSG16.HLP >> wininit.ini
echo NUL=%winbootdir%\AWSG32.HLP >> wininit.ini
echo NUL=%winbootdir%\AIAXS16.DLL >> wininit.ini   
echo NUL=%winbootdir%\AIAXS32.DLL >> wininit.ini   
echo NUL=%winbootdir%\LWSG_API.DLL >> wininit.ini   
echo NUL=%winbootdir%\WSGUTIL.DLL >> wininit.ini   
echo NUL=%winbootdir%\WSGUTIL.DLL >> wininit.ini    
echo NUL=%winbootdir%\WSGAPI16.DLL >> wininit.ini   
echo NUL=%winbootdir%\AIXLDR16.EXE >> wininit.ini  
echo NUL=%winbootdir%\WST16NB.DLL >> wininit.ini  
echo NUL=%winbootdir%\WSTNB_32.DLL >> wininit.ini   
echo NUL=%winbootdir%\AIXLDR32.EXE >> wininit.ini   
echo NUL=%winbootdir%\WSSERVER.DLL >> wininit.ini  
echo NUL=%winbootdir%\SYSTEM\WSGVUTIL.VXD >> wininit.ini  
echo NUL=%winbootdir%\AWSGATE.INI >> wininit.ini  
echo NUL=%winbootdir%\STARTM~1\PROGRAMS\STARTUP\LANTAS~1.LNK >> wininit.ini
echo %winbootdir%\system\wsock32.dll=%winbootdir%\system\wsock32.000 >> wininit.ini
echo.
echo.
echo   Reenabling original Winsock files. . .
if not exist %winbootdir%\winsock.000 goto :WinsockError
  copy %winbootdir%\winsock.000 %winbootdir%\winsock.dll /Y > nul
  goto :PastWinsockError

:WinsockError
echo.
echo   WINSOCK.000 was not found in %winbootdir%.  Unable to rename to WINSOCK.DLL.
echo   If this machine is a winsock gateway server, this is normal.
echo.
echo   If this machine is a winsock client, you will have to extract WINSOCK.DLL 
echo   from your Windows 95 CD-ROM or copy from another Windows 95 machine to 
echo   the WINDOWS directory.
echo.
echo   Please refer to the GATEUNST.TXT text file for further details.
echo.
pause

:PastWinsockError
echo.
echo.

if not exist %winbootdir%\system\wsock32.000 goto :WS32Error
  goto :UnInstall


:WS32Error
echo   WSOCK32.000 not found in %winbootdir%\SYSTEM. Unable to rename to WSOCK32.DLL.
echo.
echo   If this machine is a winsock client, you will have to extract WINSOCK.DLL from
echo   your Windows 95 CD-ROM or copy from another Windows 95 machine to the WINDOWS
echo.
echo   If copying file from diskette, restart system in DOS mode to avert a sharing
echo   violation.
echo.
echo.
pause
echo.


:UnInstall
echo.

echo NUL=%winbootdir%\gateunst.ini >> wininit.ini
echo Starting Uninstall program to clean up. . .
echo.
echo Do not be alarmed about the next screen which warns that part of LANtastic
echo is being uninstalled.  Just click 'Ok' to continue when prompted.
echo.
pause

ltuninst %winbootdir%\gateunst.ini
exit



:Win31x         No WinBootdir variable set...Should be 3.1x

set 31GATEERR=
cls
echo.
echo         LANtastic Winsock Gateway Removal Program for DOS/Windows 3.1x

echo.
echo   This screen should appear in a DOS / Windows 3.1x environment.
echo.
echo   If you are running Windows '95/98, abort this program.  You will need to
echo   set the environmental variable WINBOOTDIR to reflect the directory in
echo   which Windows 95 is installed.  
echo   For example, enter the DOS command SET winbootdir=C:\WINDOWS.
echo   This program may then be relaunched and the Windows '95 initialization
echo   screen should appear.
echo.
echo.
echo   This program permanently removes the LANtastic Winsock Gateway feature of
echo   LANtastic 7.0.  Should you later wish to reenable this feature it will be 
echo   necessary to reinstall LANtastic 7.0 either from CD or from an Install 
echo   resource once this program has completed.
echo.
echo            Press Ctrl-C to abort or
echo.
pause

cls
if exist aixldr16.exe goto :RemoveFiles
C:                      rem Didn't find main file.  Look around a little.
CD\Windows
Cls
if exist aixldr16.exe goto :RemoveFiles
echo LANtastic Gateway files were not found in the current directory.
echo Please change to the directory where Windows is installed and rerun
echo this program.
set 31GATEERR=1
goto :End               rem Things aren't in default areas. Punt and warn user.


:RemoveFiles            rem We're in the right place.  Get rid of the files.
echo Removing WST16NB.DLL
Del WST16NB.DLL 

echo Removing WSTAPI16.DLL
Del WSTAPI16.DLL

echo Removing AIAXS16.DLL
Del AIAXS16.DLL 

echo Removing AWSG16.HLP
Del AWSG16.HLP 

echo Removing AWSGATE.INI
Del AWSGATE.INI

echo Removing AIXLDR16.EXE
Del AIXLDR16.EXE

echo Removing WINSOCK.DLL
Del WINSOCK.DLL 

:FindOldWinsock
Copy WINSOCK.001 WINSOCK.DLL
if errorlevel 0 goto :LastScreen
echo   A previous version of WINSOCK.DLL was not found in 
echo.
cd
echo.
echo   Unable to rename to WINSOCK.DLL.
echo   This may be a normal condition as Windows 3.1x does not provide a WINSOCK.DLL
echo   by default.  It may be necessary to either copy WINSOCK.DLL from elsewhere,
echo   into the Windows directory or ensure that WINSOCK.DLL is located in the 
echo   system search path.
pause

:LastScreen
echo   LANtastic Internet Gateway files removed.
echo.

:End
Set WINTEST=